快速入门：使用 CMake 构建
本教程旨在帮助您使用 CMake 快速启动并运行 GoogleTest。如果您是第一次使用 GoogleTest 或需要复习，我们建议您从本教程开始。如果您的项目使用 Bazel，请参阅Bazel 快速入门。
先决条件
要完成本教程，您需要：
- 兼容的操作系统（例如 Linux、macOS、Windows）。
- 兼容的 C++ 编译器，至少支持 C++17。
- CMake 和兼容的构建工具来构建项目。
有关与 GoogleTest 兼容的平台的更多信息，请参阅支持的平台。
如果您尚未安装 CMake，请参阅 CMake 安装指南。
注意：本教程中的终端命令显示 Unix shell 提示符，但这些命令也适用于 Windows 命令行。
设置项目
CMake 使用名为 CMakeLists.txt 的文件来配置项目的构建系统。您将使用此文件来设置您的项目并声明对 GoogleTest 的依赖。
首先，为您的项目创建一个目录
$ mkdir my_project && cd my_project
接下来，您将创建 CMakeLists.txt 文件并声明对 GoogleTest 的依赖。在 CMake 生态系统中，有很多方法可以表达依赖关系；在本快速入门中，您将使用 FetchContent CMake 模块。为此，在您的项目目录 (my_project) 中，创建一个名为 CMakeLists.txt 的文件，内容如下：
cmake_minimum_required(VERSION 3.14)
project(my_project)
# GoogleTest requires at least C++17
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
include(FetchContent)
FetchContent_Declare(
googletest
URL https://github.com/google/googletest/archive/03597a01ee50ed33e9dfd640b249b4be3799d395.zip
)
# For Windows: Prevent overriding the parent project's compiler/linker settings
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
FetchContent_MakeAvailable(googletest)
上面的配置声明了对 GoogleTest 的依赖，该依赖从 GitHub 下载。在上面的示例中，03597a01ee50ed33e9dfd640b249b4be3799d395 是要使用的 GoogleTest 版本的 Git 提交哈希值；我们建议经常更新哈希值以指向最新版本。
有关如何创建 CMakeLists.txt 文件的更多信息，请参阅 CMake 教程。
创建并运行二进制文件
将 GoogleTest 声明为依赖项后，您可以在自己的项目中使用 GoogleTest 代码。
例如，在您的 my_project 目录中创建一个名为 hello_test.cc 的文件，内容如下：
#include <gtest/gtest.h>
// Demonstrate some basic assertions.
TEST(HelloTest, BasicAssertions) {
// Expect two strings not to be equal.
EXPECT_STRNE("hello", "world");
// Expect equality.
EXPECT_EQ(7 * 6, 42);
}
GoogleTest 提供了 断言，您可以使用它们来测试代码的行为。上面的示例包括主要的 GoogleTest 头文件，并演示了一些基本断言。
要构建代码，请将以下内容添加到 CMakeLists.txt 文件的末尾
enable_testing()
add_executable(
hello_test
hello_test.cc
)
target_link_libraries(
hello_test
GTest::gtest_main
)
include(GoogleTest)
gtest_discover_tests(hello_test)
上面的配置启用了 CMake 中的测试，声明了您想要构建的 C++ 测试二进制文件 (hello_test)，并将其链接到 GoogleTest (gtest_main)。最后两行使 CMake 的测试运行程序能够发现二进制文件中包含的测试，使用 GoogleTest CMake 模块。
现在您可以构建并运行您的测试
my_project$ cmake -S . -B build
-- The C compiler identification is GNU 10.2.1
-- The CXX compiler identification is GNU 10.2.1
...
-- Build files have been written to: .../my_project/build
my_project$ cmake --build build
Scanning dependencies of target gtest
...
[100%] Built target gmock_main
my_project$ cd build && ctest
Test project .../my_project/build
Start 1: HelloTest.BasicAssertions
1/1 Test #1: HelloTest.BasicAssertions ........ Passed 0.00 sec
100% tests passed, 0 tests failed out of 1
Total Test time (real) = 0.01 sec
恭喜！您已成功使用 GoogleTest 构建并运行了测试二进制文件。